Cleanest way to prematurely exit a Jenkins Pipeline job as a success?

Question

I have a job that will create files, unless one of the values being fed to it matches an older value. What's the cleanest way in Jenkins to abort or exit the job, without it being FAILED? It exiting is the correct behavior so I want the build marked SUCCESS.

It'll end up in an if statement like so;

stage ('Check value') {

     if( $VALUE1 == $VALUE2 ) {
       //if they do match exit as a success, else continue with the rest of the job 
    }

}

I don't want to throw an error code unless that can somehow translate into it being marked a successful build.

score 98 · Accepted Answer · edited Sep 20 '21 at 14:06

Please note: The following works for scripted pipelines only. For a solution for declarative pipelines see @kgriffs' answer.

---

Figured it out. Outside of any stages (otherwise this will just end the particular stage as a success) do the following;

if( $VALUE1 == $VALUE2 ) {
   currentBuild.result = 'SUCCESS'
   return
}

return will stop the stage or node you're running on which is why running it outside of a stage is important, while setting the currentBuild.result prevents it from failing.

Ben Amos · Answer 2 · 2020-01-16T23:10:13.997

The Executor.interrupt(Result) method is the cleanest, most direct way I could find to stop a build prematurely and mark it as a success.

script {
    currentBuild.getRawBuild().getExecutor().interrupt(Result.SUCCESS)
    sleep(1)   // Interrupt is not blocking and does not take effect immediately.
}

Pros:

Works in a declarative pipeline just as well as a scripted one.
No try/catch or exceptions to handle.
Marks the calling stage and any successive stages as green/passing in the UI.

Cons:

Requires a number of in-process script approvals, including one that is considered insecure. Approve and use with caution.

score 23 · Answer 3 · answered Jul 10 '18 at 11:29

You can also use error to exit the current stage, then you don't have to consider the current stage hierarchy and similar stuff:

def autoCancelled = false

try {
  stage('checkout') {
    ...
    if (your condition) {
      autoCancelled = true
      error('Aborting the build.')
    }
  }
} catch (e) {
  if (autoCancelled) {
    currentBuild.result = 'SUCCESS'
    // return here instead of throwing error to keep the build "green"
    return
  }
  // normal error handling
  throw e
}

But this would lead to a red stage, if the error occurs within a stage.

It depends on your requirements, which way you want to use.

score 15 · Answer 4 · edited Sep 19 '21 at 12:06

If it is acceptable to set the build status to ABORTED instead of SUCCESS, the following snippet may be used within a pipeline stage to short-circuit the build:

steps {
    script {
        currentBuild.result = 'ABORTED'
        error("Aborting the build.")
    }
}

I tested setting the result to SUCCESS, but doing so resulted in a failed build (using Jenkins 2.235.5). It seems that ABORTED is respected by the error step, while SUCCESS is overridden.

score 4 · Answer 5 · answered May 07 '20 at 00:55

I was almost able to accomplish this with declarative pipeline. This allows you to exit the before the pipeline starts based on the outcome of a shell script. I was not able to get this working within the pipeline itself (either within or between stages).

node('master'){
    env.status_code = sh(script: 'exit 0 # or 200 or other', returnStatus:true)
}
println 'status_code: ' + env.status_code
if(env.status_code == '200'){
    println 'Now is not the time to run the pipeline.'
    println 'Exiting without running subsequent stages.'
    currentBuild.result = 'SUCCESS'
    return
} else if(env.status_code == '0'){
    println 'Time to run. Let\'s go!'
} else {
    error 'Unable to check if it\'s time to run.'
}

pipeline {
  agent any
  stages {
      stage('Run only if exit status for was 0'){
          steps{
             sh 'echo hi'
          }
      }
  }
}

when directive may help if you only want to skip certain stages, not exit entirely.

https://www.jenkins.io/doc/book/pipeline/syntax/#when

score 1 · Answer 6 · edited Jul 11 '23 at 15:44

1

Honestly you shouldn't need to use the exit command specifically, but there is a Conditional BuildStep Plugin which may achieve the same end result (code that doesn't run).

I haven't come up against this yet, so haven't used the plugin.

There is also conditionals as found in this prior Stack Overflow post on Jenkins: Jenkins Pipeline Conditional Step/Stage

edited Jul 11 '23 at 15:44

Community

1

answered Apr 14 '17 at 21:30

MrMesees

111
5

score 0 · Answer 7 · edited May 27 '25 at 15:22

Go to "Manage Jenkins" -> "In-process Script Approval" and write below line in 'Signatures already approved:' box

new org.jenkinsci.plugins.workflow.steps.FlowInterruptedException hudson.model.Result jenkins.model.CauseOfInterruption[]

Now in your pipeline, add below lines,

currentBuild.result = "SUCCESS"
throw new org.jenkinsci.plugins.workflow.steps.FlowInterruptedException(hudson.model.Result.SUCCESS)

This worked for me.

Example Jenkinsfile,

pipeline {
    agent any
    environment {
        ENVIRONMENT = "skip"
    }
stages {
    stage('Check Conditions') {
        steps {
            script {
                if (env.ENVIRONMENT == 'skip') {
                    echo &quot;Skipping pipeline for this environment...&quot;

                    currentBuild.result = &quot;SUCCESS&quot;
                    throw new org.jenkinsci.plugins.workflow.steps.FlowInterruptedException(hudson.model.Result.SUCCESS)

                }

            }
        }
    }

    stage('Next Stage') {
        steps {

            echo &quot;This won't run if ENVIRONMENT was 'skip'&quot;

        }
    }

}

}

To make the state as 'Aborted' instead of Success, one can use below lines,

currentBuild.result = "ABORTED"
throw new org.jenkinsci.plugins.workflow.steps.FlowInterruptedException(hudson.model.Result.ABORTED)

References:

Cleanest way to prematurely exit a Jenkins Pipeline job as a success?

7 Answers7